# A gyakorló feladatlap megoldása
> restart;
> with(plots):
# 1. feladat
# Legyen  f  az  f(x)=x^2 tg(x+1)  hozzárendeléssel és a D_f=[-2,2] 
# értelmezési tartománnyal megadva.
# 
# a) Ábrázold egy rajzon f és f' grafikonját! Ez alapján állapítsd meg 
# f  lokális szélsőértékhelyeit!
> 
> f:=x^2*tan(x+1);

                                2
                          f := x  tan(x + 1)

> fv:=diff(f, x);

                                     2                2
             fv := 2 x tan(x + 1) + x  (1 + tan(x + 1) )

> pf:=plot(f, x=-2..2, -10..10, discont = true, color=red):
> pfv:=plot(fv, x=-2..2, -10..10, discont = true, color=blue):
> display(pf, pfv, title=`f:piros, f':kék`);

# f-nek csak ott lehet lokális sz. é.-e, ahol fv=0, és biztosan van is,
# ha fv eljelet vált.
#  A rajz alapján x=-0.64 és x=0 lok. sz. é.  és más nincs is.
# 
# b) Megforgatjuk f grafikonjának [-1,0] feletti részét az x-tengely
# körül
# 360 fokkal. Mennyi a keletkező forgástest palástjának területe? Ha
# tudod, akkor a pontos eredményt add meg, ha nem lehet, akkor 5
# tizedesjegyre
# pontosan!  
> palast_ter:=2*Pi*int( f*sqrt(1+fv^2), x=-1..0);

                        0
                       /
                      |    2
  palast_ter := 2 Pi  |   x  tan(x + 1)
                      |
                     /
                       -1

                                    2                2  2
        sqrt(1 + (2 x tan(x + 1) + x  (1 + tan(x + 1) )) ) dx

# A fenti eredménybl látszik, hogy az integrált a Maple nem tudja zárt
# alakban kifejezni
# (valószínleg nem is lehet). Ezért közelítünk:
> evalf(palast_ter, 5);

                                .59158

# 
# 2.  Legyen g(x,y)=ch(y)/(x^2+2)   és  h(x,y)=ch(y)(x^2+2).
# 
# Melyik függvénynek van lokális szélsőértékhelye az origó közelében és
# hol?
# Rajzold ki ezen pont közelében a függvény gradiensét!
> g:=cosh(y)/(x^2+2);
> h:=cosh(y)*(x^2+2);

                                  cosh(y)
                             g := -------
                                   2
                                  x  + 2


                                       2
                        h := cosh(y) (x  + 2)

> plot3d(g, x=-0.5..0.5, y=-0.5..0.5, axes=boxed, style=patchcontour,
> shading=zhue, title=`g grafikonja`);

> plot3d(h, x=-0.5..0.5, y=-0.5..0.5, axes=boxed, style=patchcontour,
> shading=zhue, title=`h grafikonja`);

# Innen látszik, hogy g-nek nyeregpontja, h-nak lok. min-a van az
# origóban.
# 
# grad_h az origó körül:
> fieldplot([diff(h,x), diff(h,y)], x=-0.5..0.5, y=-0.5..0.5,
> grid=[11,11], axes=boxed, title=`grad_h grfikonja`);

# 3. A megfelelő mátrixok bevezetésével oldd meg az alábbi
# egyenletrendszert!
#     2y+3z=3 ,     -x+2y+4z=-2,    2x+y=1
> with(linalg):
> A := matrix( [[0,2,3],[-1,2,4],[2,1,0]] );
> b := vector( [3,-2,1]);

                              [ 0    2    3]
                              [            ]
                         A := [-1    2    4]
                              [            ]
                              [ 2    1    0]


                           b := [3, -2, 1]

> linsolve(A, b, 'rang', t);

                            [-16, 33, -21]

# Más módszerrel:
> evalm( inverse(A) &* b );

                            [-16, 33, -21]

# Tehát a megoldás: x=-16, y=33, z=-21.
# 
# 4.  Rajzold ki az alábbi kezdeti érték feladat megoldásának
# grafikonját az [1,20] intervallumon!
# y'=(2-x)(x+y^2),  y(1)=2
> diffegy:=diff(y(x), x)=(2-x)/(x+y(x)^2);

                               d           2 - x
                    diffegy := -- y(x) = ---------
                               dx                2
                                         x + y(x)

> kezdfelt:=y(1)=2;

                         kezdfelt := y(1) = 2

> dsolve( {diffegy,kezdfelt}, y(x));
# Mivel nem kaptunk függvényt megoldásként, ezért közelítö megoldásra
# van szükség.
# 
> nummegold:=dsolve( {diffegy,kezdfelt}, y(x), numeric);

                 nummegold := proc(rkf45_x)  ...  end

# Próba, hogy tényleg kaptunk-e valamit:
> nummegold(1.5);

                 [x = 1.5, y(x) = 2.069989241662746]

> ynum:=x->rhs(nummegold(x)[2]);

                  ynum := x -> rhs(nummegold(x)[2])

# Próba:
> ynum(1.5);

                          2.069989241662746

> plot('ynum(x)', x=1..20);

>